Neste tutorial vamos aprender a monitorar o status da sessão BGP no RouterOS v6 o nosso “querido” Mikrotik, bem como receber notificações se a sessão cair ou reconectar.

Como a mikrotik não disponibiliza essas informações via SNMP das sessões BGP, usaremos das artimanhas. Então juntamente com meu amigo Saulo Costa qual identificou que existe uma OID dos script que estão no RouterOS (1.3.6.1.4.1.14988.1.1.8.1.1.2) e outra (1.3.6.1.4.1.14988.1.1.18.1.1.2.***) que é possivel executar-lo bem como ter retornos, e ai meu amigo as mentes voaram longe!

Acompanhe o raciocínio:

1º Crie um script em seu RouterOS

Darei o nome do script de bgp_snmp

:put "{\"peer\": [";
:global lista [/routing bgp peer find];
:global contador 0;
:foreach i in=$lista do={
  :global disabled [/routing bgp peer get value-name=disabled number=$i];
  :global name [/routing bgp peer get value-name=name number=$i];
  :global remoteaddress [/routing bgp peer get value-name=remote-address number=$i];
  :global remoteas [/routing bgp peer get value-name=remote-as number=$i];
  :global state [/routing bgp peer get value-name=state number=$i];
    :if (state = "idle") do={:set state 1;};
    :if (state = "connect") do={:set state 2;}
    :if (state = "active") do={:set state 3;}; 
    :if (state = "opensent") do={:set state 4;}
    :if (state = "openconfirm") do={:set state 5;}; 
    :if (state = "established") do={:set state 6;}
    :if (disabled = true) do={:set state 1;}
  :global prefix [/routing bgp peer get value-name=prefix number=$i];
    :if (prefix < 1) do={:set prefix 0;}  
  :global uptime [/routing bgp peer get value-name=uptime number=$i];
    :if (uptime < 1) do={:set uptime 0;}
    :global uptimeseconds 0; :global weekend 0; 
    :global dayend 0; :global weeks 0; :global days 0;
    :if ([:find $uptime "w" -1] > 0) do={
      :set weekend [:find $uptime "w" -1];
      :set weeks [:pick $uptime 0 $weekend];
      :set weekend ($weekend+1);
    };
    :if ([:find $uptime "d" -1] > 0) do={
      :set dayend [:find $uptime "d" -1];
      :set days [:pick $uptime $weekend $dayend];
    };
    :global time [:pick $uptime ([:len $uptime]-8) [:len $uptime]]; 
    :global hours [:pick $time 0 2];
    :global minutes [:pick $time 3 5];
    :global seconds [:pick $time 6 8]; 
    :set uptimeseconds [($weeks*86400*7+$days*86400+$hours*3600+$minutes*60+$seconds)];

  :set contador ($contador + 1);
  :if ( $contador < [:len $lista]) do={
    :put "{\"Id\": \"$contador\",\"Disabled\": \"$disabled\",\"Name\": \"$name\",\"Remote-Address\": \"$remoteaddress\",\"Remote-AS\": \"$remoteas\",\"State\": \"$state\",\"Prefix\": \"$prefix\",\"Uptime\": \"$uptimeseconds\"},"
  } else={
    :put "{\"Id\": \"$contador\",\"Disabled\": \"$disabled\",\"Name\": \"$name\",\"Remote-Address\": \"$remoteaddress\",\"Remote-AS\": \"$remoteas\",\"State\": \"$state\",\"Prefix\": \"$prefix\",\"Uptime\": \"$uptimeseconds\"}"
  };
  };
:put "]}";

A idéa é pegar as informações no scrip e apenas imprimi-las. Experimente executar o script agora!

[user@mikrotik] > system script run bgp_snmp

Você terá uma saída em JSON com as informações que iremos coletar lá no Zabbix.

{"peer": [
{"Id": "1","Disabled": "false","Name": "VS_BORDA_IPv4","Remote-Address": "10.50.50.29","Remote-AS": "1234","State": "6","Prefix": "1","Uptime": "83235"},
{"Id": "2","Disabled": "false","Name": "VS_BORDA_IPv6","Remote-Address": "fd00:bacb:50:28::1","Remote-AS": "1234","State": "6","Prefix": "1","Uptime": "3500"}
]}

2º Configure o SNMP

Será necessário habiliar o write-access, então tenha certeza de ter uma community fora dos padrões (ex public {mando te matar!}) bem como restringir o acesso apenas para IP ou Prefixos de seus servidores.
Segue um exemplo:

/snmp community set [ find default=yes ] addresses=200.200.200.0/28 name=sUpErS3cret0 write-access=yes
/snmp set contact="noc@remontti.com.br" enabled=yes location="Seu Local" trap-version=2

3º Teste do seu servidor Zabbix

No exemplo meu router tem o IP 10.50.50.30 e minha community é sUpErS3cret0. Se você não tem as MIBS e o comando snmpwalk não "funciona" leia aqui.

# snmpwalk -v2c -c sUpErS3cret0 10.50.50.30 1.3.6.1.4.1.14988.1.1.8.1.1.2

Você tera um resultado com todos os seus scripts:

SNMPv2-SMI::enterprises.14988.1.1.8.1.1.2.1 = STRING: "bakup_ftp"
SNMPv2-SMI::enterprises.14988.1.1.8.1.1.2.4 = STRING: "script_da_morte"
SNMPv2-SMI::enterprises.14988.1.1.8.1.1.2.7 = STRING: "bgp_snmp"

O que é iportante para nós é esse numerozinho aqui: 14988.1.1.8.1.1.2.7, mais propriamente dito o final dele, neste exemplo o nº 7, este é o identificador do script. Anote ele, vamos precisar ele lá no nosso template.
Agora vamos rodar o script e fazer um get para ver se temos o retorno com o OID 1.3.6.1.4.1.14988.1.1.18.1.1.2.X. Onde X é o nº do identificador do script (neste ex 7).

# snmpget -v2c -c sUpErS3cret0 10.50.50.30 1.3.6.1.4.1.14988.1.1.18.1.1.2.7 |  sed -e 's/\\//g'

Você irá receber uma saída com todos os peers do seu router:

SNMPv2-SMI::enterprises.14988.1.1.18.1.1.2.8 = STRING: "{"peer": [
{"Id": "1","Disabled": "false","Name": "VS_BORDA_IPv4","Remote-Address": "10.50.50.29","Remote-AS": "1234","State": "6","Prefix": "1","Uptime": "84508"},
{"Id": "2","Disabled": "false","Name": "VS_BORDA_IPv6","Remote-Address": "fd00:bacb:50:28::1","Remote-AS": "1234","State": "6","Prefix": "1","Uptime": "4773"}
]}"

4º Importando o template para o Zabbix

Faça download do template RR Mikrotik - BGP - SNMP Script.xml e importe o mesmo.

5º Crie/Edite um host usando o template

Informe o Nome, grupo bem como IP com agente SNMP.

Selecione o template RR Mikrotik - BGP - SNMP Script

Lembra do identificador, precisamos informa-lo aqui.

Acesse os dados recentes para verificar se os itens foram criados (lembrado que ele é executado a cada 5min) então tenha paciência de aguardar 10min ou execute manualmente.

Bem mais simplique que o metodo do outro tutorial com script python.

Espero que tenha gostado! E mais uma vez deixo meu agradecimento ao parceio Saulo. Se fizer algo legal não deixe de compartilhar! Com isso você pode criar até mesmo outros templates, para coletar outras informações. Isso é o legal de compartilhar!

Se quiser fazer uma doação para o café ficarei muito feliz pelo seu reconhecimento!

Se não puder doar pode deixar seu agradecimento nos comentário também ficarei feliz em saber que ajudei. Se tiver qualquer pergunta deixe-a também. Se preferir entrar em Contato clique aqui.

O post Monitorando no Zabbix as sessões BGP do RouterOS v6 (Mikrotik) via SNMP apareceu primeiro em Remontti.